SHOP ZERO

　クラブ等に良くあるダンスボールスクリプトを作ってみました。
ボールをタッチするとコンテンツの中にあるアニメーションをダイアログ表示し、
選んだアニメーションを実行します。
ダンスをストップするときは、ダイアログ右上の"STOP"ボタンを押します。
アニメーションは、ボールにドラッグするだけでＯＫです。

＜スクリプト内容＞
//
//   DanceBall script   v1.1
//                                                                 
//                                       Created by Zero2000 Kid     2007/11/10
//                                                                                    2007/12/08(modified)
//                                                             　　　　　　　　　　　　　
list list_anim;
string anim;
integer handle;

getAminlist() {
       list_anim=[];
       integer i;
       integer animct = llGetInventoryNumber(INVENTORY_ANIMATION);
       for (i = 0; i < animct; i++) {
               if (i<11) list_anim+=llGetInventoryName(INVENTORY_ANIMATION,i);
       }
       list_anim+="STOP";
}

stopAnimation() {
       list anims = llGetAnimationList(llGetPermissionsKey());
       integer aminct = llGetListLength(anims);
       integer i;
       for (i = 0; i < aminct; i++){
               llStopAnimation(llList2Key(anims, i));
       }
       // add 2007/12/8  -->
       llStartAnimation("stand");
      //  <--
}

startAnimation() {
       stopAnimation();
       if (anim!="STOP") {
               llStartAnimation(anim);
       }
}

default {
       
       state_entry() {
               llSetText("Let's Dance\nClick Me!",<1,1,1>, 1.0);
               getAminlist();   
       }
       
       on_rez(integer int) {
               llResetScript(); 
       }
       
       changed(integer change){
               if (change & CHANGED_INVENTORY){
                       getAminlist();
               }
       }
       
       touch_start(integer t) {
               handle = llListen(-1,"", "","");
               llDialog(llDetectedKey(0), "PLEASE SELECT DANCE", list_anim, -1);
       }
       
       listen(integer ch, string name, key id, string message) {
               anim=message;
               if ((llGetPermissions() & PERMISSION_TRIGGER_ANIMATION) 
                                               && llGetPermissionsKey() == id) {
                       startAnimation();
               } else { 
                       llRequestPermissions(id, PERMISSION_TRIGGER_ANIMATION); 
               }
               llListenRemove(handle);
       }
       
       run_time_permissions(integer perm){ 
               if(perm & PERMISSION_TRIGGER_ANIMATION){ 
                       startAnimation();
               } 
       }
}

＜スクリプトの説明＞
1. アニメーションをコンテンツにドラッグするとchangedイベントが発生し、そのタイミングでアニメー
　ションの名前を取得し、リストに格納します。
2. ボールをタッチするとllListenコマンドでリッスンモードをスタートし、llDialogで、アニメのリストを
　ダイアログ表示します。
3. アニメを選択するとリッスンイベントが発生し、llRequestPermissionsでパーミションを取得した後、
　　アニメーションをスタートします。

ええｗかなり説明省いてます・・・いいのかこんなんでｗ
ちょっと時間ないのでこの辺でｗ


リンデンスクリプト Tips Intexへ