SHOP ZERO

ドリンクサーバのスクリプトです。
サーバをクリックするとダイアログを表示し、選んだドリンクを渡します。
ドリンクは、サーバのコンテンツの中にドラッグするだけでＯＫです。
最大１２個までのドリンクに対応しています。


* メニューにはドリンク以外のものもありますが、オブジェクトならなんでもＯＫですｗｗ

「スクリプト内容」
//
//   Drink Server script   v1.0
//
//                   Created by Zero2000 Kid     2007/11/21
//

integer ItemType=INVENTORY_OBJECT;
integer input_ch = -1;
integer Itemct;
integer num;
integer handle;
list Itemlist;
string ItemName;


getItemlist() {
    Itemlist=[];
    integer i;
    Itemct = llGetInventoryNumber(ItemType);
    if (Itemct>12) Itemct=12;
    for (i = 0; i < Itemct; i++) {
        Itemlist+=llGetInventoryName(ItemType,i);
    }
}

default {

    state_entry() {
        llSetText("Drink Server\nClick me , Drink Gets !.", <1,1,1>, 1.0);
        getItemlist();
    }

    on_rez(integer int) {
        llResetScript(); 
    }

    touch_start(integer t) {
        if (Itemct!=0) {
            handle = llListen(input_ch,"",llDetectedKey(0),"");
            llDialog(llDetectedKey(0), "PLEASE SELECT DRINK MENU", Itemlist, input_ch);
        }
    }
    
    changed(integer change){
        if (change & CHANGED_INVENTORY){
            getItemlist();
        }
    }
    
    listen(integer ch, string name, key id, string message) {
        llGiveInventory(id,message);
        llWhisper(0,llKey2Name(id) + " got " + message + ".");
        llListenRemove(handle);
    }

}


「スクリプトの説明」
　1. state_entry発生時、またはコンテンツの中に変化があったとき関数getItemlist()を呼び出します。
　2. 関数getItemlist()では、llGetInventoryNumber及びllGetInventoryNameを使用し、コンテンツの中
　  のオブジェクトを名前を取得し、リスト変数Itemlistに格納します。
　3. オブジェクトがクリックされるとtouchイベントの中で、リッスンコマンドを実行し、ドリンクのダイアログ
　　　メニューを表示します。
　4. ダイアログからメニューを選択するとリッスンイベントが発生し、llGiveInventoryでメニューで選択した
　　　名称のオブジェクトを渡します。



リンデンスクリプト Tips Intexへ



タグ ：ドリンクtipsフリースクリプトlslリンデンスクリプト

はじめまして。スクリプト初心者です。
こちらのアイテムをフリーアイテムの配布に使いたいのですがこのスクリプトで１２個以上のオブジェクトを配布するにはどうすればいいのでしょうか。

sataさん

はじめまして＾＾
お返事遅くなりました。

　ダイアログのボタンの数は、最大12個と決まっていますので、それ以上を
扱い時は、別に新しいダイアログをを出す等の工夫が必要です。例えばボタ
ンの１つを切り替え用のボタンとして用意し、そのボタンが押されれば次の
ダイアログを表示するような作りにすればOKです。
下記のスクリプトは、22個のアイテムに対応した内容です。

integer ItemType=INVENTORY_OBJECT;
integer input_ch = -1;
integer Itemct;
integer num;
integer handle;
list Itemlist1;
list Itemlist2;
string ItemName;


getItemlist() {
Itemlist1=[];
Itemlist2=[];
integer i;
Itemct = llGetInventoryNumber(ItemType);
if (Itemct>22) Itemct=22;
for (i = 0; i < Itemct; i++) {
if (i<11) {
Itemlist1+=llGetInventoryName(ItemType,i);
} else {
Itemlist2+=llGetInventoryName(ItemType,i);
}
}
Itemlist1+="NEXT";
Itemlist2+="BACK";
}

default {

state_entry() {
llSetText("Drink Server\nClick me , Drink Gets !.", <1,1,1>, 1.0);
getItemlist();
}

on_rez(integer int) {
llResetScript();
}

touch_start(integer t) {
if (Itemct!=0) {
handle = llListen(input_ch,"",llDetectedKey(0),"");
llDialog(llDetectedKey(0), "PLEASE SELECT DRINK MENU", Itemlist1, input_ch);
}
}

changed(integer change){
if (change & CHANGED_INVENTORY){
getItemlist();
}
}

listen(integer ch, string name, key id, string message) {
if (message=="NEXT") {
llDialog(id, "PLEASE SELECT DRINK MENU", Itemlist2, input_ch);
} else if (message=="BACK") {
llDialog(id, "PLEASE SELECT DRINK MENU", Itemlist1, input_ch);
} else {
llGiveInventory(id,message);
llWhisper(0,llKey2Name(id) + " got " + message + ".");
llListenRemove(handle);
}
}

}

なるほど、次のダイアログが表示されるようにできるのですね。

ありがとうございますｗ

はじめましてSLName　hiroy Boaと申します。スクリプト色々使わせていただきます。zeroさんのブログを観てすごくスクリプトに興味がわいてきました。頑張って勉強しようと思います。
貴重なスクリプトの掲載ありがとうございます。

このブログでスクリプトに興味持って頂いてとても嬉しく思います。
困ったことがればいつでも相談してくださいね＾＾